键盘是由若干按键组成的开关矩阵，它是微型计算机最常用的输入设备，用户能够经过键盘向计算机输入指令、地址和数据。一般单片机体系中采和非编码键盘，非编码键盘是由软件来辨认键盘上的闭合键，它具有结构简略，运用灵敏等特色，因而被广泛使用于单片机体系。
按键开关的颤动问题
组成键盘的按键有触点式和非触点式两种，单片机中使用的一般是由机械触点构成的。鄙人图中，当开关S未被按下时，P1。0输入为高电平，S闭合后，P1。0输入为低电平。由于按键是机械触点，当机械触点断开、闭合时，会有颤动动，P1。0输入端的波形如图2所示。这种颤动关于人来说是感觉不到的，但对计算机来说，则是完全能够感应到的，由于计算机处理的速度是在微秒级，而机械颤动的时刻至少是毫秒级，对计算机而言，这已是一个“绵长”的时刻了。前面咱们讲到中止时曾有个问题，便是说按键有时灵，有时不灵，其实便是这个原因，你只按了一次按键，但是计算机却已履行了屡次中止的进程，假如履行的次数正好是奇数次，那么成果正如你所料，假如履行的次数是偶数次，那就不对了。
为使CPU能正确地读出P1口的状况，对每一次按键只作一次呼应，就必须考虑怎么去除颤动，常用的去颤动的办法有两种：硬件办法和软件办法。单片机中常用软件法，因而，关于硬件办法咱们不介绍。软件法其实很简略，便是在单片机取得P1。0口为低的信息后，不是当即确定S1已被按下，而是延时10毫秒或更长一些时刻后再次检测P1。0口，假如仍为低，阐明S1的确按下了，这实践上是避开了按键按下时的颤动时刻。而在检测到按键开释后（P1。0为高）再延时5-10个毫秒，消除后沿的颤动，然后再对键值处理。不过一般情况下，咱们一般不对按键开释的后沿进行处理，实践证明，也能满意必定的要求。当然，实践使用中，对按键的要求也是千差万别，要根据不同的需要来编制处理程序，但以上是消除键颤动的准则。
2.键盘与单片机的衔接
1、经过1/0口衔接。将每个按键的一端接到单片机的I/O口，另一端接地，这是最简略的办法，如图3所示是试验板上按键的接法，四个按键别离接到P3.2 、P3.3、P3.4和P3.5。关于这种键各程序能够选用不断查询的办法，功用便是：检测是否有键闭合，如有键闭合，则去除键颤动，判别键号并转入相应的键处理。下面给出一个例程。其功用很简略，四个键界说如下：
P3.2：开端，按此键则灯开端活动（由上而下）
P3.3：中止，按此键则中止活动，一切灯为暗
P3.4：上，按此键则灯由上向下活动
P3.5：下，按此键则灯由下向上活动
UpDown EQU 00H ;上下行标志
StartEnd EQU 01H ;起动及中止标志
LAMPCODE EQU 21H ;寄存活动的数据代码
ORG 0000H
AJMP MAIN
ORG 30H
MAIN:
MOV SP,#5FH
MOV P1,#0FFH
CLR UpDown ;发动时处于向上的状况
CLR StartEnd ;发动时处于中止状况
MOV LAMPCODE,#0FEH ;单灯活动的代码
LOOP:
ACALL KEY ;调用键盘程序
JNB F0,LNEXT ;假如无键按下，则持续
ACALL KEYPROC ;不然调用键盘处理程序
LNEXT:
ACALL LAMP ;调用灯显现程序
AJMP LOOP ;重复循环，主程序到此结束
;—————————————
DELAY:
MOV R7,#100
D1: MOV R6,#100
DJNZ R6,$
DJNZ R7,D1
RET
;—————————————-延时程序，键盘处理中调用
KEYPROC:
MOV A,B ;从B寄存器中获取键值
JB ACC.2,KeyStart ;剖析键的代码，某位被按下，则该位为1（由于在键盘程序中已取反）
JB ACC.3,KeyOver
JB ACC.4,KeyUp
JB ACC.5,KeyDown
AJMP KEY_RET
KeyStart:
SETB StartEnd ;第一个键按下后的处理
AJMP KEY_RET
KeyOver:
CLR StartEnd ;第二个键按下后的处理
AJMP KEY_RET
KeyUp: SETB UpDown ;第三个键按下后的处理
AJMP KEY_RET
KeyDown:
CLR UpDown ;第四个键按下后的处理
KEY_RET:RET
KEY:
CLR F0 ;清F0，表明无键按下。
ORL P3,#00111100B ;将P3口的接有键的四方位1
MOV A,P3 ;取P3的值
ORL A,#11000011B ;将其他4方位1
CPL A ;取反
JZ K_RET ;假如为0则必定无键按下
ACALL DELAY ;不然延时去键抖
ORL P3,#00111100B
MOV A,P3
ORL A,#11000011B
CPL A
JZ K_RET
MOV B,A ;的确有键按下，将键值存入B中
SETB F0 ;设置有键按下的标志
K_RET:
ORL P3,#00111100B ;此处循环等候键的开释
MOV A,P3
ORL A,#11000011B
CPL A
JZ K_RET1 ;直到读取的数据取反后为0阐明键开释了，才从键盘处理程序中回来
AJMP K_RET
K_RET1:
RET
;———————————–
D500MS: ;流水灯的延迟时刻
PUSH PSW
SETB RS0
MOV R7,#200
D51: MOV R6,#250
D52: NOP
NOP
NOP
NOP
DJNZ R6,D52
DJNZ R7,D51
POP PSW
RET
;———————————–
LAMP:
JB StartEnd,LampStart ;假如StartEnd=1，则发动
MOV P1,#0FFH
AJMP LAMPRET ;不然封闭一切显现，回来
LampStart:
JB UpDown,LAMPUP ;假如UpDown=1，则向上活动
MOV A,LAMPCODE
RL A ;实践便是左移位罢了
MOV LAMPCODE,A
MOV P1,A
LCALL D500MS
AJMP LAMPRET
LAMPUP:
MOV A,LAMPCODE
RR A ;向下活动实践便是右移
MOV LAMPCODE,A
MOV P1,A
LCALL D500MS
LAMPRET:
RET
END
以上程序功用很简略，但它演示了一个键盘处理程序的基本思路，程序自身很简略，也不很有用，实践工作中还会有很多要考虑的要素，比方主循环每次都调用灯的循环程序，会形成按键反响“愚钝”，而假如一向按着键不放，则灯不会再活动，一向要到松开手停止，等等，我们能够细心考虑一下这些问题，再想想有什么好的解决办法。
2、选用中止方法：如图4所示。各个按键都接到一个与非上，当有任何一个按键按下时，都会使与门输出为低电平，然后引起单片机的中止，它的优点是不用在主程序中不断地循环查询，假如有键按下，单片机再去做相应的处理。
