装载ARM Linux内核发动进程

注: 本文转自ChinaUnix 作者为XPL.

本文针对arm linux, 从kernel的第一条指令开端剖析,一向剖析到进入 start_kernel()函数. 咱们当时以linux-2.6.19内核版别作为典范来剖析,本文中一切的代码,前面都会加上行号以便于和源码进行对照, 例: 在文件init/main.c中: 00478: asmlinkage void init start_kernel(void) 前面的”00478:” 标明478行,冒号后边的内容便是源码了.

在剖析代码的进程中,咱们运用缩进来标明各个代码的调用层次.

由于发动部分有一些代码是渠道特定的,尽管大部分的渠道所完结的功用都比较相似,可是为了更好的对code进行阐明,关于渠道相关的代码,咱们挑选 at91(ARM926EJS)渠道进行剖析.

别的,本文是以uncompressed kernel开端解说的.关于内核解压缩部分的code,在 arch/arm/boot/compressed中,本文不做评论.

一. 发动条件

一般从体系上电到履行到linux kenel这部分的使命是由boot loader来完结. 关于boot loader的内容,本文就不做过多介绍. 这儿只评论进入到linux kernel的时分的一些约束条件,这一般是boot loader在终究跳转到kernel之前要完结的:

• 1. CPU有必要处于SVC(supervisor)形式,而且IRQ和FIQ中止都是制止的;
• 2. MMU(内存办理单元)有必要是封闭的, 此刻虚拟地址对物理地址;
• 3. 数据cache(Data cache)有必要是封闭的
• 4. 指令cache(Instruction cache)可所以翻开的,也可所以封闭的,这个没有强制要求;
• 5. CPU 通用寄存器0 (r0)有必要是 0;
• 6. CPU 通用寄存器1 (r1)有必要是 ARM Linux machine type (关于machine type, 咱们后边会有解说)
• 7. CPU 通用寄存器2 (r2) 有必要是 kernel parameter list 的物理地址(parameter list 是由boot loader传递给kernel,用来描绘设备信息特点的列表,具体内容可参阅”Booting ARM Linux”文档).

二. starting kernel

首要，咱们先对几个重要的宏进行阐明(咱们针对有MMU的状况)：

宏	方位	默认值	阐明
KERNEL_RAM_ADDR	arch/arm/kernel/head.S +26	0xc0008000	kernel在RAM中的的虚拟地址
PAGE_OFFSET	include/asm-arm/memeory.h +50	0xc0000000	内核空间的开端虚拟地址
TEXT_OFFSET	arch/arm/Makefile +137	0x00008000	内核相关于存储空间的偏移
TEXTADDR	arch/arm/kernel/head.S +49	0xc0008000	kernel的开端虚拟地址
PHYS_OFFSET	include/asm-arm/arch-xxx/memory.h	渠道相关	RAM的开端物理地址

内核的进口是stext,这是在arch/arm/kernel/vmlinux.lds.S中界说的:

00011: ENTRY(stext)

关于vmlinux.lds.S,这是ld script文件,此文件的格局和汇编及C程序都不同,本文不对ld script作过多的介绍,只对内核中用到的内容进行解说,关于ld的具体内容能够参阅ld.info 这儿的ENTRY(stext) 标明程序的进口是在符号stext. 而符号stext是在arch/arm/kernel/head.S中界说的: 下面咱们将arm linux boot的首要代码列出来进行一个归纳的介绍,然后,咱们会逐一的进行具体的解说.

在arch/arm/kernel/head.S中 72 – 94 行,是arm linux boot的主代码: 00072: ENTRY(stext)
00073: msr cpsr_c, #PSR_F_BIT | PSR_I_BIT | SVC_MODE @ ensure svc mode
00074: @ and irqs disabled
00075: mrc p15, 0, r9, c0, c0 @ get processor id
00076: bl __lookup_processor_type @ r5=procinfo r9=cpuid
00077: movs r10, r5 @ invalid processor (r5=0)?
00078: beq __error_p @ yes, error p
00079: bl __lookup_machine_type @ r5=machinfo
00080: movs r8, r5 @ invalid machine (r5=0)?
00081: beq __error_a @ yes, error a
00082: bl __create_page_tables
00083:
00084: /*
00085: * The following calls CPU specific code in a position independent
00086: * manner. See arch/arm/mm/proc-*.S for details. r10 = base of
00087: * xxx_proc_info structure selected by __lookup_machine_type
00088: * above. On return, the CPU will be ready for the MMU to be
00089: * turned on, and r0 will hold the CPU control register value.
00090: */
00091: ldr r13, __switch_data @ address to jump to after
00092: @ mmu has been enabled
00093: adr lr, __enable_mmu @ return (PIC) address
00094: add pc, r10, #PROCINFO_INITFUNC

其间,73行是确保kernel运转在SVC形式下,而且IRQ和FIRQ中止现已封闭,这样做是很慎重的.

arm linux boot的主线能够归纳为以下几个过程:

• 1. 确认 processor type (75 – 78行)
• 2. 确认 machine type (79 – 81行)
• 3. 创立页表 (82行)
• 4. 调用渠道特定的cpu_flush函数 (在struct proc_info_list中) (94 行)
• 5. 敞开mmu (93行)
• 6. 切换数据 (91行)

终究跳转到start_kernel (在switch_data的完毕的时分,调用了 b start_kernel)

下面,咱们依照这个主线,逐渐的剖析Code.

1. 确认 processor type

arch/arm/kernel/head.S中:

00075: mrc p15, 0, r9, c0, c0 @ get processor id
00076: bl __lookup_processor_type @ r5=procinfo r9=cpuid
00077: movs r10, r5 @ invalid processor (r5=0)?
00078: beq __error_p @ yes, error p

75行: 经过cp15协处理器的c0寄存器来获得processor id的指令. 关于cp15的具体内容可参阅相关的arm手册

76行: 跳转到lookup_processor_type.在lookup_processor_type中,会把processor type 存储在r5中

77,78行: 判别r5中的processor type是否是0,假如是0,阐明是无效的processor type,跳转到error_p(犯错)

lookup_processor_type 函数首要是依据从cpu中获得的processor id和体系中的proc_info进行匹配,将匹配到的proc_info_list的基地址存到r5中, 0标明没有找到对应的processor type.

下面咱们剖析lookup_processor_type函数

arch/arm/kernel/head-common.S中:

00145: .type __lookup_processor_type, %function
00146: __lookup_processor_type:
00147: adr r3, 3f
00148: ldmda r3, {r5 – r7}
00149: sub r3, r3, r7 @ get offset between virt&phys
00150: add r5, r5, r3 @ convert virt addresses to
00151: add r6, r6, r3 @ physical address space
00152: 1: ldmia r5, {r3, r4} @ value, mask
00153: and r4, r4, r9 @ mask wanted bits
00154: teq r3, r4
00155: beq 2f
00156: add r5, r5, #PROC_INFO_SZ @ sizeof(proc_info_list)
00157: cmp r5, r6
00158: blo 1b
00159: mov r5, #0 @ unknown processor
00160: 2: mov pc, lr
00161:
00162: /*
00163: * This provides a C-API version of the above function.
00164: */
00165: ENTRY(lookup_processor_type)
00166: stmfd sp!, {r4 – r7, r9, lr}
00167: mov r9, r0
00168: bl __lookup_processor_type
00169: mov r0, r5
00170: ldmfd sp!, {r4 – r7, r9, pc}
00171:
00172: /*
00173: * Look in include/asm-arm/procinfo.h and arch/arm/kernel/arch.[ch] for
00174: * more information about the __proc_info and __arch_info structures.
00175: */
00176: .long __proc_info_begin
00177: .long __proc_info_end
00178: 3: .long .
00179: .long __arch_info_begin
00180: .long __arch_info_end

145, 146行是函数界说

147行: 取地址指令,这儿的3f是向前symbol称号是3的方位,即第178行,将该地址存入r3.

这儿需求留意的是,adr指令取址,获得的是依据pc的一个地址,要分外留意,这个地址是3f处的”运转时地址”,由于此刻MMU还没有翻开,也能够了解成物理地址(实地址).(具体内容可参阅arm指令手册)

148行: 由于r3中的地址是178行的方位的地址,因此履行完后:

r5存的是176行符号 proc_info_begin的地址; r6存的是177行符号 proc_info_end的地址; r7存的是3f处的地址. 这儿需求留意链接地址和运转时地址的差异. r3存储的是运转时地址(物理地址),而r7中存储的是链接地址(虚拟地址).

proc_info_begin和proc_info_end是在arch/arm/kernel/vmlinux.lds.S中:

00031: __proc_info_begin = .;
00032: *(.proc.info.init)
00033: __proc_info_end = .;

这儿是声明晰两个变量:proc_info_begin 和 proc_info_end,其间等号后边的”.”是location counter(具体内容请参阅ld.info) 这三行的意思是: proc_info_begin 的方位上,放置一切文件中的 “.proc.info.init” 段的内容,然后紧接着是 proc_info_end 的方位.

kernel 运用struct proc_info_list来描绘processor type.

在 include/asm-arm/procinfo.h 中:

00029: struct proc_info_list {
00030: unsigned int cpu_val;
00031: unsigned int cpu_mask;
00032: unsigned long __cpu_mm_mmu_flags; /* used by head.S */
00033: unsigned long __cpu_io_mmu_flags; /* used by head.S */
00034: unsigned long __cpu_flush; /* used by head.S */
00035: const char *arch_name;
00036: const char *elf_name;
00037: unsigned int elf_hwcap;
00038: const char *cpu_name;
00039: struct processor *proc;
00040: struct cpu_tlb_fns *tlb;
00041: struct cpu_user_fns *user;
00042: struct cpu_cache_fns *cache;
00043: };

咱们当时以at91为例,其processor是926的.
在arch/arm/mm/proc-arm926.S 中:
00464: .section “.proc.info.init”, #alloc, #execinstr
00465:
00466: .type __arm926_proc_info,#object
00467: __arm926_proc_info:
00468: .long 0x41069260 @ ARM926EJ-S (v5TEJ)
00469: .long 0xff0ffff0
00470: .long PMD_TYPE_SECT | \
00471: PMD_SECT_BUFFERABLE | \
00472: PMD_SECT_CACHEABLE | \
00473: PMD_BIT4 | \
00474: PMD_SECT_AP_WRITE | \
00475: PMD_SECT_AP_READ
00476: .long PMD_TYPE_SECT | \
00477: PMD_BIT4 | \
00478: PMD_SECT_AP_WRITE | \
00479: PMD_SECT_AP_READ
00480: b __arm926_setup
00481: .long cpu_arch_name
00482: .long cpu_elf_name
00483: .long HWCAP_SWP|HWCAP_HALF|HWCAP_THUMB|HWCAP_FAST_MULT|HWCAP_VFP|HWCAP_EDSP|HWCAP_JAVA
00484: .long cpu_arm926_name
00485: .long arm926_processor_functions
00486: .long v4wbi_tlb_fns
00487: .long v4wb_user_fns
00488: .long arm926_cache_fns
00489: .size __arm926_proc_info, . – __arm926_proc_info

从464行,咱们能够看到 arm926_proc_info 被放到了”.proc.info.init”段中. 对照struct proc_info_list,咱们能够看到 cpu_flush的界说是在480行,即arm926_setup.(咱们将在”4. 调用渠道特定的cpu_flush函数”一节中具体剖析这部分的内容.)

从以上的内容咱们能够看出: r5中的proc_info_begin是proc_info_list的开端地址, r6中的proc_info_end是proc_info_list的完毕地址.

149行: 从上面的剖析咱们能够知道r3中存储的是3f处的物理地址,而r7存储的是3f处的虚拟地址,这一行是核算当时程序运转的物理地址和虚拟地址的差值,将其保存到r3中.

150行: 将r5存储的虚拟地址(proc_info_begin)转换成物理地址

151行: 将r6存储的虚拟地址(proc_info_end)转换成物理地址

152行: 对照struct proc_info_list,能够得知,这句是将当时proc_info的cpu_val和cpu_mask别离存r3, r4中

153行: r9中存储了processor id(arch/arm/kernel/head.S中的75行),与r4的cpu_mask进行逻辑与操作,得到咱们需求的值

154行: 将153行中得到的值与r3中的cpu_val进行比较

155行: 假如持平,阐明咱们找到了对应的processor type,跳到160行,回来

156行: (假如不持平) , 将r5指向下一个proc_info,

157行: 和r6比较,查看是否到了proc_info_end.

158行: 假如没有到proc_info_end,标明还有proc_info装备,回来152行持续查找

159行: 履行到这儿,阐明一切的proc_info都匹配过了,可是没有找到匹配的,将r5设置成0(unknown processor)

160行: 回来

2. 确认 machine type

arch/arm/kernel/head.S中:

00079: bl __lookup_machine_type @ r5=machinfo
00080: movs r8, r5 @ invalid machine (r5=0)?
00081: beq __error_a @ yes, error a

79行: 跳转到lookup_machine_type函数,在lookup_machine_type 中,会把struct machine_desc的基地址(machine type)存储在r5中 80,81行: 将r5中的 machine_desc的基地址存储到r8中,并判别r5是否是0,假如是0,阐明是无效的machine type,跳转到error_a(犯错)

lookup_machine_type 函数 下面咱们剖析lookup_machine_type 函数:

arch/arm/kernel/head-common.S中:

00176: .long __proc_info_begin
00177: .long __proc_info_end
00178: 3: .long .
00179: .long __arch_info_begin
00180: .long __arch_info_end
00181:
00182: /*
00183: * Lookup machine architecture in the linker-build list of architectures.
00184: * Note that we cant use the absolute addresses for the __arch_info
00185: * lists since we arent running with the MMU on (and therefore, we are
00186: * not in the correct address space). We have to calculate the offset.
00187: *
00188: * r1 = machine architecture number
00189: * Returns:
00190: * r3, r4, r6 corrupted
00191: * r5 = mach_info pointer in physical address space
00192: */
00193: .type __lookup_machine_type, %function
00194: __lookup_machine_type:
00195: adr r3, 3b
00196: ldmia r3, {r4, r5, r6}
00197: sub r3, r3, r4 @ get offset between virt&phys
00198: add r5, r5, r3 @ convert virt addresses to
00199: add r6, r6, r3 @ physical address space
00200: 1: ldr r3, [r5, #MACHINFO_TYPE] @ get machine type
00201: teq r3, r1 @ matches loader number?
00202: beq 2f @ found
00203: add r5, r5, #SIZEOF_MACHINE_DESC @ next machine_desc
00204: cmp r5, r6
00205: blo 1b
00206: mov r5, #0 @ unknown machine
00207: 2: mov pc, lr

193, 194行: 函数声明

195行: 取地址指令,这儿的3b是向后symbol称号是3的方位,即第178行,将该地址存入r3.

和上面咱们对lookup_processor_type 函数的剖析相同,r3中寄存的是3b处物理地址.

196行:

• r3是3b处的地址,因此履行完后:
• r4存的是 3b处的地址
• r5存的是arch_info_begin 的地址
• r6存的是arch_info_end 的地址

arch_info_begin 和 arch_info_end是在 arch/arm/kernel/vmlinux.lds.S中:

00034: __arch_info_begin = .;
00035: *(.arch.info.init)
00036: __arch_info_end = .;

这儿是声明晰两个变量:arch_info_begin 和 arch_info_end,其间等号后边的”.”是location counter(具体内容请参阅ld.info) 这三行的意思是: arch_info_begin 的方位上,放置一切文件中的 “.arch.info.init” 段的内容,然后紧接着是 arch_info_end 的方位.

kernel 运用struct machine_desc 来描绘 machine type. 在 include/asm-arm/mach/arch.h 中:

00017: struct machine_desc {
00018: /*
00019: * Note! The first four elements are used
00020: * by assembler code in head-armv.S
00021: */
00022: unsigned int nr; /* architecture number */
00023: unsigned int phys_io; /* start of physical io */
00024: unsigned int io_pg_offst; /* byte offset for io
00025: * page tabe entry */
00026:
00027: const char *name; /* architecture name */
00028: unsigned long boot_params; /* tagged list */
00029:
00030: unsigned int video_start; /* start of video RAM */
00031: unsigned int video_end; /* end of video RAM */
00032:
00033: unsigned int reserve_lp0 :1; /* never has lp0 */
00034: unsigned int reserve_lp1 :1; /* never has lp1 */
00035: unsigned int reserve_lp2 :1; /* never has lp2 */
00036: unsigned int soft_reboot :1; /* soft reboot */
00037: void (*fixup)(struct machine_desc *,
00038: struct tag *, char **,
00039: struct meminfo *);
00040: void (*map_io)(void);/* IO mapping function */
00041: void (*init_irq)(void);
00042: struct sys_timer *timer; /* system tick timer */
00043: void (*init_machine)(void);
00044: };
00045:
00046: /*
00047: * Set of macros to define architecture features. This is built into
00048: * a table by the linker.
00049: */
00050: #define MACHINE_START(_type,_name) \
00051: static const struct machine_desc __mach_desc_##_type \
00052: __attribute_used__ \
00053: __attribute__((__section__(“.arch.info.init”)) = { \
00054: .nr = MACH_TYPE_##_type, \
00055: .name = _name,
00056:
00057: #define MACHINE_END \
00058: };

内核中,一般运用宏MACHINE_START来界说machine type.
关于at91, 在 arch/arm/mach-at91rm9200/board-ek.c 中:
00137: MACHINE_START(AT91RM9200EK, “Atmel AT91RM9200-EK”
00138: /* Maintainer: SAN People/Atmel */
00139: .phys_io = AT91_BASE_SYS,
00140: .io_pg_offst = (AT91_VA_BASE_SYS >> 1 & 0xfffc,
00141: .boot_params = AT91_SDRAM_BASE + 0x100,
00142: .timer = &at91rm9200_timer,
00143: .map_io = ek_map_io,
00144: .init_irq = ek_init_irq,
00145: .init_machine = ek_board_init,
00146: MACHINE_END

197行: r3中存储的是3b处的物理地址,而r4中存储的是3b处的虚拟地址,这儿核算处物理地址和虚拟地址的差值,保存到r3中

198行: 将r5存储的虚拟地址(arch_info_begin)转换成物理地址 199行: 将r6存储的虚拟地址(arch_info_end) 转换成物理地址 200行: MACHINFO_TYPE 在 arch/arm/kernel/asm-offset.c 101行界说, 这儿是取 struct machine_desc中的nr(architecture number) 到r3中

201行: 将r3中取到的machine type 和 r1中的 machine type(见前面的”发动条件”进行比较

202行: 假如相同,阐明找到了对应的machine type,跳转到207行的2f处,此刻r5中存储了对应的struct machine_desc的基地址

203行: (不相同), 取下一个machine_desc的地址

204行: 和r6进行比较,查看是否到了arch_info_end.

205行: 假如不相同,阐明还有machine_desc,回来200行持续查找.

206行: 履行到这儿,阐明一切的machind_desc都查找完了,而且没有找到匹配的, 将r5设置成0(unknown machine).

207行: 回来

3. 创立页表

经过前面的两步,咱们现已确认了processor type 和 machine type. 此刻,一些特定寄存器的值如下所示:

r8 = machine info (struct machine_desc的基地址)
r9 = cpu id (经过cp15协处理器获得的cpu id)
r10 = procinfo (struct proc_info_list的基地址)

创立页表是经过函数 create_page_tables 来完结的.

这 里,咱们运用的是arm的L1主页表,L1主页表也称为段页表(section page table) L1 主页表将4 GB 的地址空间分红若干个1 MB的段(section),因此L1页表包括4096个页表项(section entry). 每个页表项是32 bits(4 bytes) 因此L1主页表占用 40964 = 16k的内存空间.

关于ARM926,其L1 section entry的格局为可参阅arm926EJS TRM):

下面咱们来剖析 create_page_tables 函数:

在 arch/arm/kernel/head.S 中:

00206: .type __create_page_tables, %function
00207: __create_page_tables:
00208: pgtbl r4 @ page table address
00209:
00210: /*
00211: * Clear the 16K level 1 swapper page table
00212: */
00213: mov r0, r4
00214: mov r3, #0
00215: add r6, r0, #0x4000
00216: 1: str r3, [r0], #4
00217: str r3, [r0], #4
00218: str r3, [r0], #4
00219: str r3, [r0], #4
00220: teq r0, r6
00221: bne 1b
00222:
00223: ldr r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
00224:
00225: /*
00226: * Create identity mapping for first MB of kernel to
00227: * cater for the MMU enable. This identity mapping
00228: * will be removed by paging_init(). We use our current program
00229: * counter to determine corresponding section base address.
00230: */
00231: mov r6, pc, lsr #20 @ start of kernel section
00232: orr r3, r7, r6, lsl #20 @ flags + kernel base
00233: str r3, [r4, r6, lsl #2] @ identity mapping
00234:
00235: /*
00236: * Now setup the pagetables for our kernel direct
00237: * mapped region.
00238: */
00239: add r0, r4, #(TEXTADDR & 0xff000000) >> 18 @ start of kernel
00240: str r3, [r0, #(TEXTADDR & 0x00f00000) >> 18]!
00241:
00242: ldr r6, =(_end – PAGE_OFFSET – 1) @ r6 = number of sections
00243: mov r6, r6, lsr #20 @ needed for kernel minus 1
00244:
00245: 1: add r3, r3, #1 << 20
00246: str r3, [r0, #4]!
00247: subs r6, r6, #1
00248: bgt 1b
00249:
00250: /*
00251: * Then map first 1MB of ram in case it contains our boot params.
00252: */
00253: add r0, r4, #PAGE_OFFSET >> 18
00254: orr r6, r7, #PHYS_OFFSET
00255: str r6, [r0]

…

00314: mov pc, lr
00315: .ltorg

206, 207行: 函数声明

208行: 经过宏 pgtbl 将r4设置成页表的基地址(物理地址)

宏pgtbl 在 arch/arm/kernel/head.S 中:

00042: .macro pgtbl, rd
00043: ldr \rd, =(__virt_to_phys(KERNEL_RAM_ADDR – 0x4000))
00044: .endm

能够看到,页表是坐落 KERNEL_RAM_ADDR 下面 16k 的方位
宏 __virt_to_phys 是在incude/asm-arm/memory.h 中:

00125: #ifndef __virt_to_phys
00126: #define __virt_to_phys(x) ((x) – PAGE_OFFSET + PHYS_OFFSET)
00127: #define __phys_to_virt(x) ((x) – PHYS_OFFSET + PAGE_OFFSET)
00128: #endif

下面从213行 – 221行, 是将这16k 的页表清0.

213行: r0 = r4, 将页表基地址存在r0中

214行: 将 r3 置成0

215行: r6 = 页表基地址 + 16k, 能够看到这是页表的尾地址

216 – 221 行: 循环,从 r0 到 r6 将这16k页表用0填充. 223行: 获得proc_info_list的cpu_mm_mmu_flags的值,并存储到 r7中. (宏PROCINFO_MM_MMUFLAGS是在arch/arm/kernel/asm-offset.c中界说)

231行: 经过pc值的高12位(右移20位),得到kernel的section,并存储到r6中.由于当时是经过运转时地址得到的kernel的 section,因此是物理地址.

232行: r3 = r7 | (r6 << 20); flags + kernel base,得到页表中需求设置的值.

233行: 设置页表: mem+ r6 * 4 = r3

这儿,由于页表的每一项是32 bits(4 bytes),所以要乘以4(<<2).

上面这三行,设置了kernel的第一个section(物理地址地点的page entry)的页表项

239, 240行: TEXTADDR是内核的开端虚拟地址(0xc0008000), 这两行是设置kernel开端虚拟地址的页表项(留意,这儿设置的页表项和上面的231 – 233行设置的页表项是不同的 )

履行完后,r0指向kernel的第2个section的虚拟地址地点的页表项.

/TODO: 这两行的code很古怪,为什么要先取TEXTADDR的高8位(Bit31:24)0xff000000,然后再取后边的8位 (Bit23:20)0x00f00000/

242行: 这一行核算kernel镜像的巨细(bytes).

end 是在vmlinux.lds.S中162行界说的,符号kernel的完毕方位(虚拟地址):

00158 .bss : {
00159 __bss_start = .; /* BSS */
00160 *(.bss)
00161 *(COMMON)
00162 _end = .;
00163 }

kernel的size =end – PAGE_OFFSET -1, 这儿 减1的原因是由于end 是 location counter,它的地址是kernel镜像后边的一个byte的地址.

243行: 地址右移20位,核算出kernel有多少sections,并将成果存到r6中

245 – 248行: 这几行用来填充kernel一切section虚拟地址对应的页表项.

253行: 将r0设置为RAM第一兆虚拟地址的页表项地址(page entry)

254行: r7中存储的是mmu flags, 逻辑或上RAM的开端物理地址,得到RAM第一个MB页表项的值.

255行:　设置RAM的第一个MB虚拟地址的页表.

上面这三行是用来设置RAM中第一兆虚拟地址的页表. 之所以要设置这个页表项的原因是RAM的第一兆内存中或许存储着boot params.

这样,kernel所需求的根本的页表咱们都设置完了, 如下图所示

4. 调用渠道特定的 cpu_flush 函数

当 create_page_tables 回来之后

此刻,一些特定寄存器的值如下所示:r4 = pgtbl (page table 的物理基地址)r8 = machine info (struct machine_desc的基地址)r9 = cpu id (经过cp15协处理器获得的cpu id)r10 = procinfo (struct proc_info_list的基地址)

在咱们需求在敞开mmu之前,做一些有必要的作业:铲除ICache, 铲除 DCache, 铲除 Writebuffer, 铲除TLB等.

这些一般是经过cp15协处理器来完结的,而且是渠道相关的. 这便是 cpu_flush 需求做的作业.

在 arch/arm/kernel/head.S中

00091: ldr r13, __switch_data @ address to jump to after
00092: @ mmu has been enabled
00093: adr lr, __enable_mmu @ return (PIC) address
00094: add pc, r10, #PROCINFO_INITFUNC

第91行: 将r13设置为 switch_data 的地址

第92行: 将lr设置为 enable_mmu 的地址

第93行: r10存储的是procinfo的基地址, PROCINFO_INITFUNC是在 arch/arm/kernel/asm-offset.c 中107行界说.

则该即将pc设为 proc_info_list的 cpu_flush 函数的地址, 即下面跳转到该函数. 在剖析 lookup_processor_type 的时分,咱们现已知道,关于 ARM926EJS 来说,其cpu_flush指向的是函数 arm926_setup

下面咱们来剖析函数 arm926_setup

在 arch/arm/mm/proc-arm926.S 中:

00391: .type __arm926_setup, #function
00392: __arm926_setup:
00393: mov r0, #0
00394: mcr p15, 0, r0, c7, c7 @ invalidate I,D caches on v4
00395: mcr p15, 0, r0, c7, c10, 4 @ drain write buffer on v4
00396: #ifdef CONFIG_MMU
00397: mcr p15, 0, r0, c8, c7 @ invalidate I,D TLBs on v4
00398: #endif
00399:
00400:
00401: #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
00402: mov r0, #4 @ disable write-back on caches explicitly
00403: mcr p15, 7, r0, c15, c0, 0
00404: #endif
00405:
00406: adr r5, arm926_crval
00407: ldmia r5, {r5, r6}
00408: mrc p15, 0, r0, c1, c0 @ get control register v4
00409: bic r0, r0, r5
00410: orr r0, r0, r6
00411: #ifdef CONFIG_CPU_CACHE_ROUND_ROBIN
00412: orr r0, r0, #0x4000 @ .1.. …. …. ….
00413: #endif
00414: mov pc, lr
00415: .size __arm926_setup, . – __arm926_setup
00416:
00417: /*
00418: * R
00419: * .RVI ZFRS BLDP WCAM
00420: * .011 0001 ..11 0101
00421: *
00422: */
00423: .type arm926_crval, #object
00424: arm926_crval:
00425: crval clear=0x00007f3f, mmuset=0x00003135, ucset=0x00001134

第391, 392行: 是函数声明

第393行: 将r0设置为0

第394行: 铲除(invalidate)Instruction Cache 和 Data Cache.

第395行: 铲除(drain) Write Buffer.

第396 – 398行: 假如有装备了MMU,则需求铲除(invalidate)Instruction TLB 和Data TLB

接下来,是对操控寄存器c1进行装备,请参阅 ARM926 TRM.

第401 – 404行: 假如装备了Data Cache运用writethrough方法, 需求关掉write-back. 第406行:　取arm926_crval的地址到r5中, arm926_crval 在第424行 第407行:　这儿咱们需求看一下424和425行,其间用到了宏crval,crval是在 arch/arm/mm/proc-macro.S 中:

00053: .macro crval, clear, mmuset, ucset
00054: #ifdef CONFIG_MMU
00055: .word \clear
00056: .word \mmuset
00057: #else
00058: .word \clear
00059: .word \ucset
00060: #endif
00061: .endm

合作425行,咱们能够看出,首要在arm926_crval的地址处寄存了clear的值,然后接下来的地址寄存了mmuset的值(关于装备了 MMU的状况)

所以,在407行中,咱们将clear和mmuset的值别离存到了r5, r6中

第408行:　获得操控寄存器c1的值

第409行: 将r0中的 clear (r5) 对应的位都铲除去

第410行:　设置r0中 mmuset (r6) 对应的位

第411 – 413行:　假如装备了运用 round robin方法,需求设置操控寄存器c1的 Bit16

第412行: 取lr的值到pc中. 而lr中的值寄存的是 enable_mmu 的地址(arch/arm/kernel/head.S 93行),所以,接下来便是跳转到函数 enable_mmu

5. 敞开mmu

敞开mmu是又函数 enable_mmu 完结的.

在进入 enable_mmu 的时分, r0中现已寄存了操控寄存器c1的一些装备(在上一步中进行的设置), 可是并没有真实的翻开mmu,

在 enable_mmu 中,咱们将翻开mmu.

此刻,一些特定寄存器的值如下所示:

r0 = c1 parameters (用来装备操控寄存器的参数)r4 = pgtbl (page table 的物理基地址)r8 = machine info (struct machine_desc的基地址)r9 = cpu id (经过cp15协处理器获得的cpu id)r10 = procinfo (struct proc_info_list的基地址)

在 arch/arm/kernel/head.S 中:

00146: .type __enable_mmu, %function
00147: __enable_mmu:
00148: #ifdef CONFIG_ALIGNMENT_TRAP
00149: orr r0, r0, #CR_A
00150: #else
00151: bic r0, r0, #CR_A
00152: #endif
00153: #ifdef CONFIG_CPU_DCACHE_DISABLE
00154: bic r0, r0, #CR_C
00155: #endif
00156: #ifdef CONFIG_CPU_BPREDICT_DISABLE
00157: bic r0, r0, #CR_Z
00158: #endif
00159: #ifdef CONFIG_CPU_%&&&&&%ACHE_DISABLE
00160: bic r0, r0, #CR_I
00161: #endif
00162: mov r5, #(domain_val(DOMAIN_USER, DOMAIN_MANAGER) | \
00163: domain_val(DOMAIN_KERNEL, DOMAIN_MANAGER) | \
00164: domain_val(DOMAIN_TABLE, DOMAIN_MANAGER) | \
00165: domain_val(DOMAIN_IO, DOMAIN_CLIENT))
00166: mcr p15, 0, r5, c3, c0, 0 @ load domain access register
00167: mcr p15, 0, r4, c2, c0, 0 @ load page table pointer
00168: b __turn_mmu_on
00169:
00170: /*
00171: * Enable the MMU. This completely changes the structure of the visible
00172: * memory space. You will not be able to trace execution through this.
00173: * If you have an enquiry about this, *please* check the linux-arm-kernel
00174: * mailing list archives BEFORE sending another post to the list.
00175: *
00176: * r0 = cp#15 control register
00177: * r13 = *virtual* address to jump to upon completion
00178: *
00179: * other registers depend on the function called upon completion
00180: */
00181: .align 5
00182: .type __turn_mmu_on, %function
00183: __turn_mmu_on:
00184: mov r0, r0
00185: mcr p15, 0, r0, c1, c0, 0 @ write control reg
00186: mrc p15, 0, r3, c0, c0, 0 @ read id reg
00187: mov r3, r3
00188: mov r3, r3
00189: mov pc, r13

第146, 147行: 函数声明

第148 – 161行: 依据相应的装备,设置r0中的相应的Bit. (r0 将用来装备操控寄存器c1)

第162 – 165行: 设置 domain 参数r5.(r5 将用来装备domain)

第166行: 装备 domain (具体信息清参阅arm相关手册)

第167行: 装备页表在存储器中的方位(set ttb).这儿页表的基地址是r4, 经过写cp15的c2寄存器来设置页表基地址.

第168行: 跳转到 turn_mmu_on. 从称号咱们能够猜到,下面是要真实翻开mmu了.

(持续向下看,咱们会发现,turn_mmu_on就下当时代码的下方,为什么要跳转一下呢? 这是有原因的. go on)

第169 – 180行: 空行和注释. 这儿的注释咱们能够看到, r0是cp15操控寄存器的内容, r13存储了完结后需求跳转的虚拟地址(由于完结后mmu现已翻开了,都是虚拟地址了).

第181行: .algin 5 这句是cache line对齐. 咱们能够看到下面一行便是 turn_mmu_on, 之所以

第182 – 183行: turn_mmu_on 的函数声明. 这儿咱们能够看到, turn_mmu_on 是紧接着上面第168行的跳转指令的,仅仅中心在第181行多了一个cache line对齐.

这 么做的原因是: 下面咱们要进行真实的翻开mmu操作了, 咱们要把翻开mmu的操作放到一个独自的cache line上. 而在之前的”发动条件”一节咱们说了,I Cache是能够翻开也能够封闭的,这儿这么做的原因是要确保在I Cache翻开的时分,翻开mmu的操作也能正常履行.

第184行: 这是一个空操作,相当于nop. 在arm中,nop操作经常用指令 mov rd, rd 来完结.

留意: 为什么这儿要有一个nop,我考虑了很长时刻,这儿是我的猜想,或许不是正确的: 由于之前设置了页表基地址(set ttb),到下一行(185行)翻开mmu操作,中心的指令序列是这样的:

• set ttb(第167行)
• branch(第168行)
• nop(第184行)
• enable mmu(第185行)

关于arm的五级流水线: fetch – decode – execute – memory – write

他们履行的状况如下图所示:

这儿需求阐明的是,branch操作会在3个cycle中完结,而且会导致从头取指.

从这个图咱们能够看出来,在enable mmu操作取指的时分, set ttb操作刚好完结.

第185行: 写cp15的操控寄存器c1, 这儿是翻开mmu的操作,一起会翻开cache等(依据r0相应的装备)

第186行: 读取id寄存器.

第187 – 188行: 两个nop.

第189行: 取r13到pc中,咱们前面现已看到了, r13中存储的是 switch_data (在 arch/arm/kernel/head.S 91行),下面会跳到 switch_data.

第187,188行的两个nop是非常重要的,由于在185行翻开mmu操作之后,要比及3个cycle之后才会收效,这和arm的流水线有联系. 因此,在翻开mmu操作之后的加了两个nop操作.

6. 切换数据

在 arch/arm/kernel/head-common.S 中:

00014: .type __switch_data, %object
00015: __switch_data:
00016: .long __mmap_switched
00017: .long __data_loc @ r4
00018: .long __data_start @ r5
00019: .long __bss_start @ r6
00020: .long _end @ r7
00021: .long processor_id @ r4
00022: .long __machine_arch_type @ r5
00023: .long cr_alignment @ r6
00024: .long init_thread_union + THREAD_START_SP @ sp
00025:
00026: /*
00027: * The following fragment of code is executed with the MMU on in MMU mode,
00028: * and uses absolute addresses; this is not position independent.
00029: *
00030: * r0 = cp#15 control register
00031: * r1 = machine ID
00032: * r9 = processor ID
00033: */
00034: .type __mmap_switched, %function
00035: __mmap_switched:
00036: adr r3, __switch_data + 4
00037:
00038: ldmia r3!, {r4, r5, r6, r7}
00039: cmp r4, r5 @ Copy data segment if needed
00040: 1: cmpne r5, r6
00041: ldrne fp, [r4], #4
00042: strne fp, [r5], #4
00043: bne 1b
00044:
00045: mov fp, #0 @ Clear BSS (and zero fp)
00046: 1: cmp r6, r7
00047: strcc fp, [r6],#4
00048: bcc 1b
00049:
00050: ldmia r3, {r4, r5, r6, sp}
00051: str r9, [r4] @ Save processor ID
00052: str r1, [r5] @ Save machine type
00053: bic r4, r0, #CR_A @ Clear A bit
00054: stmia r6, {r0, r4} @ Save control register values
00055: b start_kernel

第14, 15行: 函数声明

第16 – 24行: 界说了一些地址,例如第16行存储的是 mmap_switched 的地址, 第17行存储的是 data_loc 的地址 ……

第34, 35行: 函数 mmap_switched

第36行: 取 switch_data + 4的地址到r3. 从上文能够看到这个地址便是第17行的地址.

第37行:　顺次取出从第17行到第20行的地址,存储到r4, r5, r6, r7 中. 而且累加r3的值.当履行完后, r3指向了第21行的方位.

对照上文,咱们能够得知:

• r4 – data_loc
• r5 – data_start
• r6 – bss_start
• r7 -end

这几个符号都是在 arch/arm/kernel/vmlinux.lds.S 中界说的变量:

00102: #ifdef CONFIG_XIP_KERNEL
00103: __data_loc = ALIGN(4); /* location in binary */
00104: . = PAGE_OFFSET + TEXT_OFFSET;
00105: #else
00106: . = ALIGN(THREAD_SIZE);
00107: __data_loc = .;
00108: #endif
00109:
00110: .data : AT(__data_loc) {
00111: __data_start = .; /* address in memory */
00112:
00113: /*
00114: * first, the init task union, aligned
00115: * to an 8192 byte boundary.
00116: */
00117: *(.init.task)

……

00158: .bss : {
00159: __bss_start = .; /* BSS */
00160: *(.bss)
00161: *(COMMON)
00162: _end = .;
00163: }

关于这四个变量,咱们简略的介绍一下:

• data_loc 是数据寄存的方位
• data_start 是数据开端的方位
• bss_start 是bss开端的方位
• end 是bss完毕的方位, 也是内核完毕的方位

其间对第110行的指令解说一下: 这儿界说了.data 段,后边的AT(data_loc) 的意思是这部分的内容是在data_loc中存储的(要留意,贮存的方位和链接的方位是能够不相同的). 关于 AT 具体的信息请参阅 ld.info

第38行: 比较 data_loc 和 data_start

第39 – 43行: 这几行是判别数据存储的方位和数据的开端的方位是否持平,假如不持平,则需求转移数据,从 data_loc 将数据搬到 data_start.

其间 bss_start 是bss的开端的方位,也标志了 data 完毕的方位,因此用其作为判别数据是否转移完结.

第45 – 48行:　是铲除 bss 段的内容,将其都置成0. 这儿运用end 来判别 bss 的完毕方位.

第50行: 由于在第38行的时分,r3被更新到指向第21行的方位.因此这儿获得r4, r5, r6, sp的值别离是:

• r4 – processor_id
• r5 – machine_arch_type
• r6 – cr_alignment
• sp – init_thread_union + THREAD_START_SP

processor_id 和 machine_arch_type 这两个变量是在 arch/arm/kernel/setup.c 中 第62, 63行中界说的. cr_alignment 是在 arch/arm/kernel/entry-armv.S 中界说的:

00182: .globl cr_alignment
00183: .globl cr_no_alignment
00184: cr_alignment:
00185: .space 4
00186: cr_no_alignment:
00187: .space 4

init_thread_union 是 init进程的基地址. 在 arch/arm/kernel/init_task.c 中:

00033: union thread_union init_thread_union
00034: __attribute__((__section__(“.init.task”))) =
00035: { INIT_THREAD_INFO(init_task) };

对照 vmlnux.lds.S 中的 的117行,咱们能够知道init task是寄存在 .data 段的开端8k, 而且是THREAD_SIZE(8k)对齐的

第51行: 将r9中寄存的 processor id (在arch/arm/kernel/head.S 75行) 赋值给变量 processor_id

第52行: 将r1中寄存的 machine id (见”发动条件”一节)赋值给变量　machine_arch_type

第53行: 铲除r0中的 CR_A 位并将值存到r4中. CR_A 是在 include/asm-arm/system.h 21行界说, 是cp15操控寄存器c1的Bit1(alignment fault enable/disable)

第54行: 这一行是存储操控寄存器的值.

从上面 arch/arm/kernel/entry-armv.S 的代码咱们能够得知. 这一句是将r0存储到了 cr_alignment 中,将r4存储到了 cr_no_alignment 中.

第55行: 终究跳转到start_kernel

FIN