X1226具有时钟和日历的功用，时钟依靠时、分、秒寄存器来盯梢，日历依靠日期、星期、月和年寄存器来盯梢，日历可正确显现至2099年，并具有主动闰年批改功用。具有强壮的双报警功用，能够被设置就任何时钟/日历值上，精确度可到1秒。可用软件设置1Hz、4096Hz或32768Hz中恣意一个频率输出。
电路组成及作业原理
X1226可与各种类型的的微操控器或微处理器接口，接口办法为串行的I2C接口。其间数据总线SDA是一个双向引脚，用于输入或输出数据。其漏极开路输出在运用过程中需求增加4.7～10kΩ的上拉电阻。本文介绍89C51单片机与X1226的接口办法，因为89C51单片机没有规范的I2C接口，只能用软件进行模仿。
|
|
为了更直观地看到时刻的改变，选用8位LED数码管显现年、月、日或时、分、秒，用PS7219A驱动LED数码管，数码管挑选0.5英寸共阴极赤色或绿色LED数码管。因为PS7219A器材内含IMP810单片机监控器材，复位输出高电平有用，因而在运用51体系时，无须增加监控器材，运用PS7219A的复位输出给51单片机复位即可，监控电压为4.63V。硬件规划原理图如图1所示。
在硬件通电调试过程中，不能用手去接触X1226的晶体振动器，不然可能会导致振动器停振，康复振动器起振的办法是封闭电源(包含备份电源)后从头上电。别的需求阐明的是，丈量振动器时，不要用示波器的探头去丈量X2的振动输出，应该用探头丈量PHZ/IRQ的振动输出，以承认是否起振和振动频率是否精确，丈量时主张在该脚加一个5.1kΩ的上拉电阻。
软件规划
X1226内含实时时钟寄存器(RTC)、状况寄存器(SR)、操控寄存器(CONTROL)、报警寄存器(Alarm0、Alarm1)和客户存储数据的存储器。因为实时时钟寄存器和状况寄存器需求进行频频的写操作，因而其存储结构为易失性SRAM结构。其他寄存器均为EEPROM结构，写操作次数一般在10万次以上。X1226初始化程序框图如图2所示，子程序YS4的作用是延时4μs。
发动条件子程序
SETB SDA
LCALL YS4
SETB SCL
LCALL YS4
CLR SDA
LCALL YS4
CLR SCL
LCALL YS4
RET
中止条件子程序
CLR SDA
LCALL YS4
SETB SCL
LCALL YS4
SETB SDA
RET
● 写操作
X1226初始化之后，单片机对X1226进行开端条件的设置，在写CCR或EEPROM之前，主机有必要先向状况寄存器写02H，承认应对信号，承认后写入06H，再承认应对信号。承认后发动了写操作，首要发送高位地
|
|
址，然后发送低位地址。X1226每收到一个地址字节后，均会发生一个应对信号。在两个地址字节都收到之后，X1226等候8位数据。在收到8位数据之后，X1226再发生一个应对，然后单片机发生一个中止条件来中止传送。
X1226具有接连写入的功用，每收到1字节后，呼应一个应对，其内部将地址加一。当计数器到达该页的结尾时，就主动回来到该页的首地址。这意味着单片机可从某一页的任何方位开端向存储器阵列接连写入64字节，或向CCR接连写入8字节的数据。写入X1226数据子程序:
MOV R5,#8
SEND1:MOV A,DATASE
RLC A
MOV DATASE,A
MOV SDA,C
SETB SCL
LCALL YS4
CLR SCL
LCALL YS4
DJNZ R5,SEND1
RET
● 读操作
在上电时，16位地址的默认值为0000H。X1226初始化操作之后，单片机对X1226进行开端条件的设置，在写CCR或EEPROM之前，主机有必要先向状况寄存器写02H，承认应对信号，承认后写入06H，再承认应对信号。承认后发动了写操作，首要发送高位地址，然后发送低位地址。X1226每收到一个地址字节后，均会发生一个应对信号。单片机发送另一个开端条件，将R/W位设置为1，接着承受8位数据。单片机中止读操作时，无需等候X1226的应对信号，单片机即可设置中止条件。读出X1226数据子程序:
MOV R5,#8
MOV DATARE,#0
SETB SDA
CLR C
READ1:SETB SCL
LCALL YS4
MOV C,SDA
CLR SCL
MOV A,DATARE
RLC A
MOV DATARE,A
LCALL YS4
DJNZ R5,READ1
RET
● 振动器频率在线补偿调理
X1226集成了振动器补偿电路，用户可经过软件在线对振动器频率进行微调，这种微调一般针对两种状况。一种状况是在25℃常温下，对振动器因器材初始精度带来的频率误差进行补偿；第二种状况是对因温度引起的频率漂移进行补偿。X1226内部设有数字微调寄存器(DTR)和模仿微调寄存器(ATR)，两个寄存器均为非易失性寄存器。数字微调寄存器具有3位数字微调位，调理规模为-30～+30×10-6。模仿微调寄存器具有6个模仿微调位，调理规模为-37～+116×10-6。
关于因外界环境温度改变引起的温漂补偿，要根据晶体的温度系数，在存储器中树立补偿参数表，不同厂家晶体的温度系数是不一样的，应根据产品数据手册进行挑选。
为了能够对温漂进行补偿，要求体系中设置一个温度传感器，并尽量让它接近X1226，这样能够真实地反映振动器的温度，原理图如图3所示。单片机首要经过体系温度传感器获取环境温度，并在补偿参数表中获取对应的补偿值，然后将补偿数据填写到相应的微调寄存器中，就能完成温漂补偿的意图。
图3
因为X1226具有精细的振动器补偿功用，因而十分适合于环境温度改变较大的使用场合，一起也降低了对晶体性能参数的要求
下面还为广大读者介绍一个程序：
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; AT89C2051时钟程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; 守时器T0、T1溢出周期为50MS，T0为秒计数用， T1为调整时闪耀用，
; P3.7为调整按钮，P1口 为字符输出口，选用共阳显现管。
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 中止进口程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ORG 0000H ;程序履行开端地址
LJMP START ;跳到标号START履行
ORG 0003H ;外中止0中止程序进口
RETI ;外中止0中止回来
ORG 000BH ;守时器T0中止程序进口
LJMP INTT0 ;跳至INTTO履行
ORG 0013H ;外中止1中止程序进口
RETI ;外中止1中止回来
ORG 001BH ;守时器T1中止程序进口
LJMP INTT1 ;跳至INTT1履行
ORG 0023H ;串行中止程序进口地址
RETI ;串行中止程序回来
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 主 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
START: MOV R0,#70H ;清70H-7AH共11个内存单元
MOV R7,#0BH ;
CLEARDISP: MOV @R0,#00H ;
INC R0 ;
DJNZ R7,CLEARDISP ;
MOV 20H,#00H ;清20H（标志用）
MOV 7AH,#0AH ;放入”平息符”数据
MOV TMOD,#11H ;设T0、T1为16位守时器
MOV TL0,#0B0H ;50MS守时初值（T0计时用）
MOV TH0,#3CH ;50MS守时初值
MOV TL1,#0B0H ;50MS守时初值（T1闪耀守时用）
MOV TH1,#3CH ;50MS守时初值
SETB EA ;总中止敞开
SETB ET0 ;答应T0中止
SETB TR0 ;敞开T0守时器
MOV R4,#14H ;1秒守时用初值（50MS×20）
START1: LCALL DISPLAY ;调用显现子程序
JNB P3.7,SETMM1 ;P3.7口为0时转时刻调整程序
SJMP START1 ;P3.7口为1时跳回START1
SETMM1: LJMP SETMM ;转到时刻调整程序SETMM
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 1秒计时程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T0中止服务程序
INTT0: PUSH ACC ;累加器入栈维护
PUSH PSW ;状况字入栈维护
CLR ET0 ;关T0中止答应
CLR TR0 ;封闭守时器T0
MOV A,#0B7H ;中止呼应时刻同步批改
ADD A,TL0 ;低8位初值批改
MOV TL0,A ;重装初值（低8位批改值）
MOV A,#3CH ;高8位初值批改
ADDC A,TH0 ;
MOV TH0,A ;重装初值（高8位批改值）
SETB TR0 ;敞开守时器T0
DJNZ R4, OUTT0 ;20次中止未到中止退出
ADDSS: MOV R4,#14H ;20次中止到（1秒）重赋初值
MOV R0,#71H ;指向秒计时单元（71H-72H）
ACALL ADD1 ;调用加1程序（加1秒操作）
MOV A,R3 ;秒数据放入A（R3为2位十进制数组合）
CLR C ;清进位标志
CJNE A,#60H,ADDMM ;
ADDMM: JC OUTT0 ;小于60秒时中止退出
ACALL CLR0 ;大于或等于60秒时对秒计时单元清0
MOV R0,#77H ;指向分计时单元（76H-77H）
ACALL ADD1 ;分计时单元加1分钟
MOV A,R3 ;分数据放入A
CLR C ;清进位标志
CJNE A,#60H,ADDHH ;
ADDHH: JC OUTT0 ;小于60分时中止退出
ACALL CLR0 ;大于或等于60分时分计时单元清0
MOV R0,#79H ;指向小时计时单元（78H-79H）
ACALL ADD1 ;小时计时单元加1小时
MOV A,R3 ;时数据放入A
CLR C ;清进位标志
CJNE A,#24H,HOUR ;
HOUR: JC OUTT0 ;小于24小时中止退出
ACALL CLR0 ;大于或等于24小时小时计时单元清0
OUTT0: MOV 72H,76H ;中止退出时将分、时计时单元数据移
MOV 73H,77H ;入对应显现单元
MOV 74H,78H ;
MOV 75H,79H ;
POP PSW ;康复状况字（出栈）
POP ACC ;康复累加器
SETB ET0 ;敞开T0中止
RETI ;中止回来
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 闪耀调时 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T1中止服务程序，用作时刻调整时调整单元闪耀指示
INTT1: PUSH ACC ;中止现场维护
PUSH PSW ;
MOV TL1, #0B0H ;装守时器T1守时初值
MOV TH1, #3CH ;
DJNZ R2,INTT1OUT ;0.3秒未到退出中止（50MS中止6次）
MOV R2,#06H ;重装0.3秒守时用初值
CPL 02H ;0.3秒守时到对闪耀标志取反
JB 02H,FLASH1 ;02H位为1时显现单元”平息”
MOV 72H,76H ;02H位为0时正常显现
MOV 73H,77H ;
MOV 74H,78H ;
MOV 75H,79H ;
INTT1OUT:
POP PSW ;康复现场
POP ACC ;
RETI ;中止退出
FLASH1: JB 01H,FLASH2 ;01H位为1时，转小时平息操控
MOV 72H,7AH ;01H位为0时，”平息符”数据放入分
MOV 73H,7AH ;显现单元（72H-73H），将不显现分数据
MOV 74H,78H ;
MOV 75H,79H ;
AJMP INTT1OUT ;转中止退出
FLASH2: MOV 72H,76H ;01H位为1时，”平息符”数据放入小时
MOV 73H,77H ;显现单元（74H-75H），小时数据将不显现
MOV 74H,7AH ;
MOV 75H,7AH ;
AJMP INTT1OUT ;转中止退出
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 加1子 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ADD1: MOV A,@R0 ;取当时计时单元数据到A
DEC R0 ;指向前一地址
SWAP A ;A中数据高四位与低四位交流
ORL A,@R0 ;前一地址中数据放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十进制调整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位变0
MOV @R0,A ;放回前一地址单元
MOV A,R3 ;取回R3中暂存数据
INC R0 ;指向当时地址单元
SWAP A ;A中数据高四位与低四位交流
ANL A,#0FH ;高四位变0
MOV @R0,A ;数据放入当削地址单元中
RET ;子程序回来
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 清零程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;对计时单元复零用
CLR0: CLR A ;清累加器
MOV @R0,A ;清当时地址单元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址单元清0
RET ;子程序回来
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 时钟调整程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;当调时按键按下时进入此程序
SETMM: cLR ET0 ;关守时器T0中止
CLR TR0 ;封闭守时器T0
LCALL DL1S ;调用1秒延时程序
JB P3.7,CLOSEDIS ;键按下时刻小于1秒，封闭显现（省电）
MOV R2,#06H ;进入调时状况，赋闪耀守时初值
SETB ET1 ;答应T1中止
SETB TR1 ;敞开守时器T1
SET2: JNB P3.7,SET1 ;P3.7口为0（键未开释），等候
SETB 00H ;键开释，分调整闪耀标志置1
SET4: JB P3.7,SET3 ;等候键按下
LCALL DL05S ;有键按下，延时0.5秒
JNB P3.7,SETHH ;按下时刻大于0.5秒转调小时状况
MOV R0,#77H ;按下时刻小于0.5秒加1分钟操作
LCALL ADD1 ;调用加1子程序
MOV A,R3 ;取调整单元数据
CLR C ;清进位标志
CJNE A,#60H,HHH ;调整单元数据与60比较
HHH: JC SET4 ;调整单元数据小于60转SET4循环
LCALL CLR0 ;调整单元数据大于或等于60时清0
CLR C ;清进位标志
AJMP SET4 ;跳转到SET4循环
CLOSEDIS:SETB ET0 ;省电（LED不显现）状况。开T0中止
SETB TR0 ;敞开T0守时器（开时钟）
CLOSE: JB P3.7,CLOSE ;无按键按下，等候。
LCALL DISPLAY ;有键按下，调显现子程序延时削抖
JB P3.7,CLOSE ;是搅扰回来CLOSE等候
WAITH: JNB P3.7,WAITH ;等候键开释
LJMP START1 ;回来主程序（LED数据显现亮）
SETHH: CLR 00H ;分闪耀标志铲除（进入调小时状况）
SETHH1: JNB P3.7,SET5 ;等候键开释
SETB 01H ;小时调整标志置1
SET6: JB P3.7,SET7 ;等候按键按下
LCALL DL05S ;有键按下延时0.5秒
JNB P3.7,SETOUT ;按下时刻大于0.5秒退出时刻调整
MOV R0,#79H ;按下时刻小于0.5秒加1小时操作
LCALL ADD1 ;调加1子程序
MOV A,R3 ;
CLR C ;
CJNE A,#24H,HOUU ;计时单元数据与24比较
HOUU: JC SET6 ;小于24转SET6循环
LCALL CLR0 ;大于或等于24时清0操作
AJMP SET6 ;跳转到SET6循环
SETOUT: JNB P3.7,SETOUT1 ;调时退出程序。等候键开释
LCALL DISPLAY ;延时削抖
JNB P3.7,SETOUT ;是颤动，回来SETOUT再等候
CLR 01H ;清调小时标志
CLR 00H ;清调分标志
CLR 02H ;清闪耀标志
CLR TR1 ;封闭守时器T1
CLR ET1 ;关守时器T1中止
SETB TR0 ;敞开守时器T0
SETB ET0 ;开守时器T0中止（计时开端）
LJMP START1 ;跳回主程序
SET1: LCALL DISPLAY ;键开释等候时调用显现程序（调分）
AJMP SET2 ;避免键按下时无时钟显现
SET3: LCALL DISPLAY ;等候调分按键时时钟显现用
AJMP SET4
SET5: LCALL DISPLAY ;键开释等候时调用显现程序（调小时）
AJMP SETHH1 ;避免键按下时无时钟显现
SET7: LCALL DISPLAY ;等候调小时按键时时钟显现用
AJMP SET6
SETOUT1: LCALL DISPLAY ;退出时钟调整时键开释等候
AJMP SETOUT ;避免键按下时无时钟显现
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 显现程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 显现数据在70H-75H单元内，用六位LED共阳数码管显现，P1口输出段码数据，P3口作
; 扫描操控，每个LED数码管亮1MS时刻再逐位循环。
DISPLAY: MOV R1,#70H ;指向显现数据首址
MOV R5,#0FEH ;扫描操控字初值
PLAY: MOV A,R5 ;扫描字放入A
MOV P3,A ;从P3口输出
MOV A,@R1 ;取显现数据到A
MOV DPTR,#TAB ;取段码表地址
MOVC A,@A+DPTR ;查显现数据对应段码
MOV P1,A ;段码放入P1口
LCALL DL1MS ;显现1MS
INC R1 ;指向下一地址
MOV A,R5 ;扫描操控字放入A
JNB ACC.5,ENDOUT ;ACC.5=0时一次显现完毕
RL A ;A中数据循环左移
MOV R5,A ;放回R5内
AJMP PLAY ;跳回PLAY循环
ENDOUT: SETB P3.5 ;一次显现完毕，P3口复位
MOV P1,#0FFH ;P1口复位
RET ;子程序回来
TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
;共阳段码表 “0””1″”2″ “3””4″”5″”6″”7″ “8””9″”不亮”
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 延时程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1MS延时程序，LED显现程序用
DL1MS: MOV R6,#14H
DL1: MOV R7,#19H
DL2: DJNZ R7,DL2
DJNZ R6,DL1
RET
;20MS延时程序，选用调用显现子程序以改进LED的显现闪耀现象
DS20MS: ACALL DISPLAY
ACALL DISPLAY
ACALL DISPLAY
RET
;延时程序，用作按键时刻的长短判别
DL1S: LCALL DL05S
LCALL DL05S
RET
DL05S: MOV R3,#20H ;8毫秒*32=0.196秒
DL05S1: LCALL DISPLAY
DJNZ R3,DL05S1
RET
;
END ;程序完毕
