;************* 电子守时器的规划******************;
;*MCU: AT892051 ;
;*MCU-crystal: 12M ;
;*Version: 01 ;
;*Last Updata: 2009-5-4 ;
;*Author:HaiZhiZi ;
;*Description: ;
;守时器T0、T1溢出周期为50MS，T0为秒计数用 ;
;S2为功用键、S3为方法挑选键 ;
;P1口为字符输出口,选用共阳显现管 ;
;P3.2~P3.5为位选,P1.7为报警发音,P3.7为被控继电器 ;
;************************************************;
;******************
; 伪界说 ;
;******************
SL EQU 30H ; SL存放秒的个位数
SH EQU 31H ; SH存放秒的十位数
ML EQU 32H ; ML存放分的个位数
MH EQU 33H ; MH存放分的十位数
HL EQU 34H ; HL存放时的个位数
HH EQU 35H ; HH存放时的十位数
;
L0 EQU 36H ; L0~L3:显现数据存储器
L1 EQU 37H
L2 EQU 38H
L3 EQU 39H
DSPLYP EQU 3AH ; 显现数据指针(DISPLAY-POINT)
PLYTS EQU 3BH ; 显现次数计数器(DISPLAY-TIMES)
;
LPLMOD BIT 39H ; 低两位显现方法(LOW-PLAY-MOD)
HPLMOD BIT 3AH ; 高两位显现方法(HIGH-PLAY-MOD)
BRIGHT BIT 3BH ; DISPLAY子程序参数:亮灭指示位
;
TCOUNT EQU 3CH ; 时刻计数器(TIME-COUNT)
;
ADDRES EQU 3DH ; 加1子程序参数
MAX EQU 3EH ; 加1子程序参数
IFDEC BIT 20H ; BCD加法子程序参数
;
R_MOD EQU 3FH ; 响铃方法参数
;
LED4 BIT 30H ; 发光管状况位
BELL BIT P1.7 ; 蜂鸣器
SWITCH BIT P3.7 ; 继电器
FKEY BIT P3.0 ; 功用键 （S1）
MKEY BIT P3.1 ; 批改键 （S2）
;
WORKIN BIT 38H ; 作业状况指示位
;
;******************
; 中止进口 ;
;******************
ORG 0000H
START: LJMP MAIN ; 0000H 引向主程序
LJMP ERR ; 0003H
NOP
NOP
LJMP ERR ; 引向犯错处理程序
LJMP PGT0 ; 000BH 引向中止处理程序PGT0
NOP
NOP
LJMP ERR ; 引向犯错处理程序
LJMP ERR ; 0013H INT1
NOP
NOP
LJMP ERR
LJMP ERR ; 001BH T1
NOP
NOP
LJMP ERR
LJMP ERR ; 0023H
NOP
NOP
LJMP ERR
LJMP ERR ; 002BH
NOP
NOP
;
;************
; 主程序 ;
;************
MAIN: MOV IE,#00H ; 关中止
MOV SP,#57H ; 设置仓库指针
MOV PSW,#00H ; 选用存放器组0
MOV TMOD,#11H ; 设定中止作业方法为T0和T1
;
MOV A,56H
CJNE A,#0AAH,CSTART ; 判上电复位标志，无标志转冷启动
MOV A,57H
CJNE A,#55H,CSTART ; 无标志转冷启动
AJMP HSTART ; 有上电复位标志转热启动
NOP
NOP
LJMP ERR ; 软件圈套,引向犯错处理程序
CSTART: MOV P1,#0FFH ; 冷启动,全面初始化
MOV P3,#0FFH
MOV TCON,#00H ; 计时中止
MOV TL0,#0B0H ; 赋中止T0初值
MOV TH0,#3CH
MOV TCOUNT,#0AH ; 赋守时器初值
MOV R5,#00H ; R5为一空单元(备用)
MOV R4,#00H ; R4 为作业形式挑选存放器
MOV SL,#00H ; 守时单元清零
MOV SH,#00H ; 秒
MOV ML,#00H ;
MOV MH,#00H ; 分
MOV HL,#00H ;
MOV HH,#00H ; 时
MOV PLYTS,#64H ; 赋显现次数初值为100次
MOV DSPLYP,#L0 ; 显现指针指向显存单元
MOV L0,#0AH ; 送显现数据”—–“
MOV L1,#0AH
MOV L2,#0AH
MOV L3,#04H
SETB LED4 ; LED4为数码管之间的发光二极管
SETB LPLMOD ; 设定显现方法为闪耀
SETB HPLMOD ;
SETB BRIGHT ; 答应显现
CLR WORKIN ; 清作业标志 , 待命
AJMP SETUP ; 转开端作业
NOP
NOP
LJMP ERR ; 软件圈套
HSTART: MOV SCON,#00H ; 有上电标志,热启动,清串行口操控存放器
MOV IP,#00H ; 清中止优先操控存放器
SETB FKEY ; 重设按键
SETB MKEY
SETB EA ; 开中止
AJMP BEGIN ; 转向持续作业
NOP
NOP
LJMP ERR ; 软件圈套
SETUP: SETB EA ; 开中止
;
MAIN1: ACALL DISPLY ; 调用显现
JB FKEY,JUDGE ; 按键扫描
ACALL KEYDLY ; 延时消颤动
JB FKEY,JUDGE ; 无键按下转向判别是否到点
CLR ET0 ; 功用键被按下,则
CLR TR0 ; 暂停计时
ACALL MENU ; 调用菜单设置程序
BEGIN: SETB WORKIN ; 置作业标志位,开端作业
SETB ET0 ; 开中止
SETB TR0 ; 开端计时
MOV A,R4 ; 移入作业形式挑选
RL A ; 指针扩大
MOV DPTR,#M_TAB
JMP @A+DPTR ; 依据作业形式跳转到相应程序段
M_TAB: AJMP WORK1
AJMP WORK2
AJMP WORK3
AJMP WORK4
NOP
NOP
LJMP ERR ; 软件圈套
WORK1: ;
WORK2: CLR SWITCH ; 作业方法1和2:开继电器
AJMP MAIN2
NOP
NOP
LJMP ERR ; 软件圈套
WORK3: ;
WORK4: SETB SWITCH ; 作业方法3和4:不开继电器
MAIN2: CLR BELL ; 蜂鸣器短鸣一声,以示开端作业
ACALL DL05S
SETB BELL
JUDGE: JNB WORKIN,MAIN1 ; 判别是否在守时之中
MOV A,SL ; 判别秒是否为零
JNZ MAIN1
MOV A,SH ; 判别秒是否为零
JNZ MAIN1
MOV A,ML ; 判别分是否为零
JNZ MAIN1
MOV A,MH ; 判别分是否为零
JNZ MAIN1
MOV A,HL ; 判别时是否为零
JNZ MAIN1
MOV A,HH ; 判别时是否为零
JNZ MAIN1 ; 若时分秒全为零则
CLR ET0 ; 中止计时
CLR TR0 ;
ACALL ACTION ; 调用到点作业子程序
AJMP MAIN ; 回来
NOP
NOP
LJMP ERR ; 软件圈套
;
;******************
; 倒计时程序 ;
;******************
PGT0: CLR EA ; 关中止
PUSH ACC ; 维护现场
PUSH PSW
PUSH DPL
PUSH DPH
MOV PSW,#08H ; 选用存放器组1
CLR TR0 ; 暂停计时
MOV A,#0B7H ; 中止同步批改
ADD A,TL0
MOV TL0,A
MOV A,#3CH
ADD A,TH0
MOV TH0,A
SETB TR0 ; 康复计时
DEC TCOUNT ; 守时器T0每50 000毫秒溢出一次,则
MOV A,TCOUNT ; 溢出10次为0.5秒
JNZ OUTT0 ; 判别是否到半秒
MOV TCOUNT,#0AH ;
CPL LED4 ; 若到半秒LED取反
JNB LED4,OUTT0 ; LED每闪耀一次是一秒
MOV R0,#SH ; 移入秒位的地址
SETB IFDEC ; BCD子程序参数,使其做减法
ACALL ADDBCD ; 调用BCD子程序, 秒减1
CJNE R3,#99H,OUTT0 ; 判别秒要否借位
MOV SH,#05H ; 要借位则
MOV SL,#09H ; 送数据59(不然显现99)
MOV R0,#MH ; 移入分位的地址
ACALL ADDBCD ; 分减1
CJNE R3,#99H,OUTT0 ; 判别分要否借位
MOV MH,#05H
MOV ML,#09H
MOV R0,#HH
ACALL ADDBCD
OUTT0: POP DPH ; 康复现场
POP DPL
POP PSW
POP ACC
SETB EA
RETI ; 中止回来
NOP
NOP
LJMP ERR ; 软件圈套
;
;
;**************************
; BCD子程序(加1或减1 ) ;
;**************************
ADDBCD: MOV A,@R0 ; 移入被操作数的高位
DEC R0 ; 指针减一
SWAP A
ORL A,@R0 ; 移入被操作数的低位
MOV B,#01H ; B存放器送当即数#01H
MOV C,IFDEC ; 若减法标志位为1,则
MOV B.3,C ;
MOV B.4,C ; B存放器的值被改为#99H
MOV B.7,C ;
ADD A,B ; 对一个紧缩的BCD码加#99H等于对其减一
DA A ; BCD码调整
MOV R3,A ; 暂存成果
ANL A,#0FH ; 取低位码
MOV @R0,A ; 存数
MOV A,R3 ; 取回成果
INC R0 ; 指针加一
SWAP A ; 交流
ANL A,#0FH ; 取成果数的高位
MOV @R0,A ; 存数
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;**************
; 加1程序 ;
;**************
ADDONE: MOV R0,ADDRES ; 移入被加数单元的地址
CLR IFDEC ; 设定BCD子程序做加法
ACALL ADDBCD ; 调用BCD子程序
CLR C ; 判别被加数是否大于
MOV A,R3 ; 最大值”MAX”
CJNE A,MAX,JGOVER
JGOVER: JC ENDADO
CLR A ; 若大于”MAX”,则清零
MOV @R0,A
DEC R0
MOV @R0,A
ENDADO: RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;******************
; 调时快进程序 ;
;******************
QUICK: CLR LPLMOD ; 设定显现方法不闪耀
CLR HPLMOD
ACALL ADDONE ; 调用加1子程序
MOV L0,R4 ; 将作业形式挑选数移入显存
INC L0 ; 加1转化成显现值
ACALL KEYDLY ; 延时
ACALL DL100
JNB MKEY,QUICK ; 判别键是否松开
SETB LPLMOD ; 若松开则康复闪耀显现方法
CJNE R6,#02H,ENDQUK
SETB HPLMOD
CLR LPLMOD
ENDQUK: RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;
;******************
; 功用菜单程序 ;
;******************
MENU: MOV R6,#00H ; 初始化; R6 计功用键按键次数
MOV ADDRES,#05H ; 将 R5 的地址送入，以便于改动 R4 的值
MOV MAX, #04H ; 界说作业形式挑选存放器R4 的最大值
MOV DSPLYP,#L0 ; 界说显现指针指向显存
SETB LPLMOD ; 设定低两位数闪耀
CLR HPLMOD
MOV L0,R4 ; 送显现数据”F-0X”
INC L0
MOV L1,#00H
MOV L2,#0BH
MOV L3,#00H
SETB LED4
;
WAITFK: ACALL DISPLY ; 等候F键开释
JNB FKEY,WAITFK
MENU1: ACALL DISPLY
JB MKEY,JGFKEY ; M键扫描
ACALL KEYDLY ; 延时消颤动
JB MKEY,JGFKEY ; 未按下则转F键扫描
CJNE R6,#00H,NEXT1 ;
MOV SL,#00H ; 若半途改动守时方法,则铲除原计时数据
MOV SH,#00H
MOV ML,#00H
MOV MH,#00H
MOV HL,#00H
MOV HH,#00H
NEXT1: MOV R2,#00H ; R2用于判别按键时刻是否超越0.5秒
NEXT2: ACALL ADDONE ; 调用加1程序
MOV L0,R4 ; 移入作业方法挑选数
INC L0
;
WAITMK: ACALL DISPLY ; 等候M键开释
INC R2 ; R2自增一
CLR C
CJNE R2,#0C8H,JGQUIC ; 若R2大于等于200则调用快进子程序
JGQUIC: JC WATMK1
ACALL QUICK
WATMK1: JNB MKEY,WAITMK ; R2小于200则等候M键开释
;
JGFKEY: JB FKEY,MENU1 ; 功用(F)键扫描
ACALL KEYDLY ; 延时消颤动
JB FKEY,MENU1 ; 键未按下则转批改(M)键扫描
INC R6 ; F键按键次数加1
MOV A,R6 ; 移入按键次数
RL A ; 指针扩大
MOV DPTR,#FUNTAB
JMP @A+DPTR ; 依据按键次数跳转到相应的程序段
FUNTAB: AJMP WAITFK
AJMP SETLOW
AJMP SETHI
AJMP ENDMEN
NOP
NOP
AJMP ENDMEN
;STWKMD: ; 作业形式设定,不需别的改动菜单
;
SETLOW: MOV MAX,#60H ; 设置低位(秒位或分位)
MOV A,R4 ; 移入作业形式挑选数
RL A ; 指针扩大
MOV DPTR,#FTAB1
JMP @A+DPTR ; 依据作业形式挑选数跳转到相应的程序段
FTAB1: AJMP SETSS
AJMP SETM60
AJMP SETSS
AJMP SETM60
NOP
NOP
AJMP WAITFK
SETSS: MOV DSPLYP,#SL ; 设定显现区域为MM:SS
MOV ADDRES,#SH
AJMP WAITFK
SETM60: MOV DSPLYP,#ML ; 设定显现区域为HH:MM
MOV ADDRES,#MH
AJMP WAITFK
;
SETHI: CLR LPLMOD ; 设置高位(分位或时位)
SETB HPLMOD ; 高两位数码管闪耀
MOV MAX,#31H ; 最大数为30
MOV A,R4 ; 移入作业形式挑选数
RL A ; 指针扩大
MOV DPTR,#FTAB2 ; 移入表首地址
JMP @A+DPTR ; 依据作业形式挑选数跳转到相应的程序段
FTAB2: AJMP SETM30
AJMP SETHH
AJMP SETM30
AJMP SETHH
NOP
NOP
AJMP WAITFK ; 回来等候键开释
SETM30: MOV ADDRES,#MH ; 移入分位的地址
AJMP WAITFK ; 转向等候键开释
SETHH: MOV ADDRES,#HH ; 移入时位的地址
AJMP WAITFK ; 转向等候键开释
;
ENDMEN: CLR HPLMOD ; 康复不闪耀显现方法
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;****************
; 到点作业程序 ;
;****************
ACTION: MOV L0,R4 ; 移入作业形式挑选数
INC L0 ; 送显现数”F-0X”
MOV L1,#00H
MOV L2,#0BH
MOV L3,#00H
SETB LED4
MOV DSPLYP,#L0 ; 指针指向显存
SETB LPLMOD ; 设定显现方法不闪耀
SETB HPLMOD
MOV A,R4 ; 移入作业形式挑选数
RL A ;
MOV DPTR,#A_TAB
JMP @A+DPTR ; 依据作业形式挑选数跳转
A_TAB: AJMP ACTF1 ; 作业形式一
AJMP ACTF1 ; 作业形式二
AJMP ACTF3 ; 作业形式三
AJMP ACTF3 ; 作业形式四
NOP
NOP
LJMP ERR ; 软件圈套
ACTF1: SETB SWITCH ; 作业形式一(或二): 关继电器
MOV R_MOD,#82H ; 响铃形式参数#82H
MOV R2,#96H ; 响铃次数参数#96H
ACTF11: ACALL RING ; 调用响铃子程序
JNB MKEY,ENDACT ; 等候键按下
JNB FKEY,ENDACT ; 有键按下则完毕响铃
DJNZ R2, ACTF11 ; 次数未满持续响铃
MOV R_MOD,#0FFH ; 参数#0FF使响铃无效
AJMP ACTF11 ; 无键按下回来
NOP
NOP
LJMP ERR ; 软件圈套
ACTF3: CLR SWITCH ; 作业形式三(或四): 开继电器
CLR BELL ; 蜂鸣器短鸣一声
ACALL DL1S
SETB BELL
MOV R_MOD,#0FFH ; 响铃形式参数#0FFH
MOV R2,#96H ; 响铃时刻参数#96H
ACTF31: ACALL RING ; 调用响铃子程序
JNB MKEY,ENDACT ; 等候键按下
JNB FKEY,ENDACT ; 有键按下则完毕
DJNZ R2,ACTF31 ; 次数未满持续
MOV R2,#96H ; 从头赋值
CLR BELL ; 短鸣一声(阐明: 响铃形式参数#0FFH使
ACALL DL100 ; 响铃程序无效,仅起延时效果,
SETB BELL ; 每延时一段时刻短鸣一声,以
AJMP ACTF31 ; 提示使用者继电器仍在作业)
NOP
NOP
LJMP ERR ; 软件圈套
ENDACT: SETB SWITCH ; 关继电器
AWAITF: ACALL DISPLY ; 调用显现
JNB FKEY,AWAITF ; 等候键开释
AWAITM: ACALL DISPLY ; 调用显现
JNB MKEY,AWAITM ; 等候键开释
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;**************
; 响铃程序 ;
;**************
RING: MOV R5,#18H ; R5为循环操控变量
RING1: JNB MKEY,R_EXIT ; 键扫描
JNB FKEY,R_EXIT ; 有键按下则退出
MOV A,R_MOD ; 移入响铃形式参数
MOV C,ACC.7 ; 依据响铃形式参数改动响铃
MOV BELL,C
RL A
MOV R_MOD,A
ACALL DL100 ; 延时
DJNZ R5,RING1 ; 循环次数操控
R_EXIT: SETB BELL ; 封闭响铃
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;**************
; 显现程序 ;
;**************
DISPLY: PUSH ACC ; 数据压栈维护
PUSH PSW
MOV PSW,#10H ; 选用存放器组2
MOV R0,DSPLYP ; 移入显现指针
MOV R2,#0FDH ; R2存放的是数码管选通数
MOV A,PLYTS ; 移入显现循环操控量
JNZ PLAY ; 不为0则转PLAY
MOV PLYTS,#64H ; 不然重新赋值
CPL BRIGHT ; 亮灭指示位取反
PLAY: DEC PLYTS ; 显现循环操控量减1
JNB LPLMOD,PLAYL ; 低两位数码管不闪则”PLAYL”
JB BRIGHT,PLAYL ; 亮灭指示为1也”PLAYL”
ACALL NOPLAY ; 不然灭灯延时
AJMP PLAY1 ; 转显现高位数码管
NOP
NOP
LJMP ERR ; 软件圈套
;用来显现低位
PLAYL: ORL P1,#7FH ; 清原显现数据
ORL P3,#3CH ; 清原选通数据
MOV A,R2 ; 移入数码管位选数
RL A ; 换一位
ANL P3,A ; 选通低位的个位数码管
MOV R2,A ; 暂存位选数
MOV A,@R0 ; 移入显现数值
MOV DPTR,#TABLE1 ; 移入表首地址
MOVC A,@A+DPTR ; 查表
ANL P1,A ; 送显现数据
ACALL DL1MS ; 延时
INC R0 ; 指向低位的十位数
JB P3.3,PLAYL ; 显现低位的十位数
;
PLAY1: JNB HPLMOD,PLAYH ; 高两位数码管不闪则”PLAYH”
JB BRIGHT,PLAYH ; 亮灭指示为1也”PLAYH”
ACALL NOPLAY ; 不然灭灯延时
AJMP OUTPLY ; 转完毕
NOP
NOP
LJMP ERR ; 软件圈套
;
;用来显现高位
PLAYH: ORL P1,#7FH ; 清原显现数据
ORL P3,#3CH ; 清原选通数据
ANL P3,#0EFH ; 选通高位的个位数数码管
MOV A,@R0 ; 移入显现数值
MOV DPTR,#TABLE1 ; 移入表首地址
MOVC A,@A+DPTR ; 查表
ANL P1,A ; 送显现数据
ACALL DL1MS ; 延时
INC R0 ; 指向高位的十位数
; ; 显现高位的十位数
ORL P1,#7FH ; 清原显现数据
ORL P3,#3CH ; 清原选通数据
ANL P3,#0DFH ; 选通高位的十位数
MOV A,@R0 ; 移入显现数值
MOV C,LED4 ; 指针扩大＋小灯状况
RLC A ;
MOV DPTR,#TABLE2 ; 移入表首地址
MOVC A,@A+DPTR ; 查表
ANL P1,A ; 送显现数据
ACALL DL1MS ; 延时
;
OUTPLY: POP PSW ; 康复数据
POP ACC
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
TABLE1: DB 0C0H,0F9H,0A4H,0B0H, 99H, 92H, 82H,0F8H, 80H, 90H,0BFH, 8EH,0FFH
; “0”, “1”, “2”, “3”, “4”, “5”, “6”, “7”, “8”, “9”, “-“, “F”, ” “
;
TABLE2: DB 0FFH, 0DFH, 0F9H, 0D9H, 0A4H, 84H, 0B0H, 90H, 0BFH, 09FH
; ” “, ” :”, “1 “, “1:”, “2 “, “2:”, “3 “, “3:”, “- “, “-:”
;
;
;
;**********************
; 无显现(灭灯)程序 ;
;**********************
NOPLAY: ORL P1,#7FH ; 清显现数据
ORL P3,#3CH ; 清选通数据
INC R0 ; 指针自增2
INC R0
ACALL DL1MS ; 延时
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;******************
; 延时程序 ;
;******************
DL1MS: MOV R3,#0F9H ; 延时 1250US 只为DISPLY所调用
DL1MS1: NOP
NOP
NOP
DJNZ R3,DL1MS1
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
KEYDLY: CLR BELL ; 按键消颤动专用延时程序,
ACALL DISPLY ; 在消除颤动的一起宣布按键提示音
SETB BELL
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
DL50MS: MOV R7,#0AH ; 50毫秒延时程序
DL50M1: ACALL DISPLY ; 每调用一次显现程序5MS
DJNZ R7,DL50M1 ; 调用10次
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
DL100: ACALL DL50MS ; 延时100毫秒
ACALL DL50MS
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
DL05S: ACALL DL100 ; 延时0.5秒
ACALL DL100
ACALL DL100
ACALL DL100
ACALL DL100
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
DL1S: ACALL DL05S ; 延时1秒
ACALL DL05S
RET
NOP
NOP
LJMP ERR ; 软件圈套
;
;****************************
; ERR(犯错处理) 程序 ;
;****************************
ERR: CLR EA ; 关中止
MOV DPTR,#ERR1 ; 预备回来地址
PUSH DPL ; 压栈
PUSH DPH ;
RETI ; 中止回来
ERR1: MOV 56H,#0AAH ; 建立上电标志(犯错标志)
MOV 57H,#55H
MOV A,#00H ; 预备回来地址
PUSH ACC ; 压栈
PUSH ACC
RETI ; 中止回来
NOP
NOP
LJMP ERR ; 软件圈套
;
ORG 07FAH
NOP
NOP
NOP
LJMP ERR ; 软件圈套
END ; 程序完毕
