一、意图
经过将 Nand Flash 前 4K 代码搬移到 SDRAM 中，了解怎么初始化并运用 ARM 的内存，
为编写 ARM bootloader 和搬移内核到内存作预备。
二、代码
关于怎么树立开发环境，在我的前一篇漫笔(FS2401 发光二极管循环点亮)里有介绍, 请
参阅。要初始化并运用内存需求了解一些很锁碎的细节，上来就讲这些知识点不免生涩，不
如在代码中交叉解说来的直接。
@ 文件 head.s
@ 效果: 封闭看门狗、设置内存、向 SDRAM 搬移 Nand Flash 的前 4K 代码、设置仓库、
@ 调用现已搬移到 SDRAM 的 main 函数
.text
.global _start
_start:
ldr r0, =0x53000000 @ Close watch-dog
mov r1, #0x0
str r1, [r0]
bl memory_setup@ Initialize memory setting
bl copy_block_to_sdram @ Move code to SDRAM
ldr sp, =0x34000000 @ Set stack pointer
ldr pc, =main @ call main in SDRAM
halt_loop:
b halt_loop
copy_block_to_sdram:
mov r0, #0x0
mov r1, #0x30000000
mov r2, #4096
copy_loop:
ldmia r0!, {r3-r10}
stmia r1!, {r3-r10}
cmp r0, r2
blo copy_loop
注:看门狗(Watch Dog Timer，简称为WDT)技能便是最常见的抗干扰技能，实际上是一个
可清零的守时计数器。
@ 文件 memory.s
@ 初始化内存操控存放器
.global memory_setup@ 导出 memory_setup, 使其对链接器可见
memory_setup:
mov r1, #0x48000000 @ BWSCON 内存操控存放器地址
adrl r2, mem_cfg_val
add r3, r1, #13*4
1:
@ write initial values to registers
ldr r4, [r2], #4
str r4, [r1], #4
cmp r1, r3
bne 1b
mov pc, lr
.align 4
mem_cfg_val:
.long 0x22111110 @ BWSCON
.long 0x00000700 @ BANKCON0
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7 9bit
.long 0x008e07a3 @ REFRESH
.long 0x000000b2 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7
注: 要了解这儿的存放器设置需求看手册和材料， 这儿简略介绍一下:
1．BWSCON：对应BANK0-BANK7，每BANK运用4位。这4位别离表明:
a．STx：发动/制止SDRAM的数据掩码引脚，对SDRAM，此位为0；对SRAM，此位为1
b．WSx：是否运用存储器的WAIT信号，一般设为0
c．DWx：运用两位来设置存储器的位宽：00-8位，01-16位，10-32位，11-保存。
d．比较特别的是BANK0对应的4位，它们由硬件跳线决议，只读。
e．关于本开发板，运用两片容量为32Mbyte、位宽为16的SDRAM组成容量为64Mbyte、
位宽为32的存储器，所以其BWSCON相应位为：0010。关于本开发板，BWSCON可设为
0x22111110：其实咱们只需求将BANK6对应的4位设为0010即可，其它的是什么值没
什么影响，这个值是参阅手册上给出的。
2．BANKCON0-BANKCON5：咱们没用到，运用默认值0x00000700即可
3．BANKCON6-BANKCON7：设为0x00018005
在8个BANK中，只要BANK6和BANK7能够运用SRAM或SDRAM，与BANKCON0-5有点不同：
a．MT([16:15])：用于设置本BANK外接的是SRAM仍是SDRAM：SRAM-0b00，SDRAM-0b11
b．当MT=0b11时，还需求设置两个参数：
Trcd([3:2])：RAS to CAS delay，设为推荐值0b01
SCAN([1:0])：SDRAM的列地址位数，本开发板的SDRAM列地址位数为9，所以SCAN=0b01
4．REFRESH(SDRAM refresh control register)：
其间R_CNT用于操控SDRAM的刷新周期，占用REFRESH存放器的[10:0]位，它的取值可
如下核算(SDRAM时钟频率便是HCLK)：
R_CNT = 2^11 + 1 – SDRAM时钟频率(MHz) * SDRAM刷新周期(uS)
在未运用PLL时，SDRAM时钟频率等于晶振频率12MHz；SDRAM的刷新周期在SDRAM的数
据手册上有标明，在本开发板运用的SDRAM HY57V561620CT-H的数据手册上，可看见
这么一行“8192 refresh cycles / 64ms”：所以，刷新周期=64ms/8192 = 7.8125 uS。
关于本试验，R_CNT = 2^11 + 1 – 12 * 7.8125 = 1955
REFRESH=0x008e0000 + 1955 = 0x008e07a3
5．BANKSIZE：0x000000b2
位[7]=1：Enable burst operation
位[5]=1：SDRAM power down mode enable
位[4]=1：SCLK is active only during the access (recommended)
位[2:1]=010 BANK6、BANK7对应的地址空间: 010-128M/128M, 001-64M/64M
6．MRSRB6、MRSRB7：0x00000030
能让咱们修正的只要位[6:4](CL)，SDRAM HY57V561620CT-H不支持CL=1的状况，所以
位[6:4]取值为010(CL=2)或011(CL=3)
/* 文件 sdram.c */
/* 效果 循环点亮开发板上的 D9、D10、D11、D12 四个发光二极管 */
#define GPFCON (*(volatile unsigned long *)0x56000050) /* GPFCON 端口地址为0x56000050 */
#define GPFDAT (*(volatile unsigned long *)0x56000054) /* GPFDAT 端口地址为0x56000054 */
int main()
{
int i,j;
while(1) {
for (i = 0; i <4; ++i) {
GPFCON = 0x1<<(8+i*2); /* 怎么设置此二存放器使二极管发光,前一*/
GPFDAT = 0x0;/* 篇漫笔(FS2401 发光二极管循环点亮) */
/* 里有介绍*/
// for delay
for(j=0;j<50000;++j) ;
}
}
}
# Makefile
# 编译上述三个代码文件， 并链接生成的方针文件,
# 再将方针文件(ELF格局)转换成二进制格局文件
sdram:head.s memory.s sdram.c
arm-linux-gcc -c -o head.o head.s
arm-linux-gcc -c -o memory.o memory.s
arm-linux-gcc -c -o sdram.o sdram.c
# -Ttext 0x30000000 会使方针文件里 ldr pc, =main 指令里的 pc 加上
# 0x30000000 这个基地址，而 #0x30000000 正是咱们要将代码搬到 SDRAM 的
# 开始地址， 更多细节请参阅 arm-linux-ld -Ttext 的用法
arm-linux-ld -Ttext 0x30000000 head.o memory.o sdram.o -o sdram_tmp.o
arm-linux-objcopy -O binary -S sdram_tmp.o sdram
clean:
rm -f *.o
rm -f sdram
三、编译、烧写、测验
Make 一下就会生成咱们要的文件 sdram, 将其经过 JTAG 烧入 Nand Flash 即可，Reset
一下开发板， 赏识您的试验效果吧
